//===== eAthena Script ======================================= 
//= Global Job Function
//===== By: ================================================== 
//= massdriller
//===== Current Version: ===================================== 
//= 0.1
//===== Compatible With: ===================================== 
//= eAthena 1.0 +
//===== Description: ========================================= 
//= Optimised scripts by moving all their checkers here.
//===== Additional Comments: ================================= 
//= For 1-1 Jobs
//============================================================ 

//Acolyte Check

function	script	Aco_check	{
		if(BaseJob == Job_Acolyte) goto JobAco;
		if(BaseJob != Job_Novice) goto NotNov;
		if(JobLevel < 10) goto JobLess10;
		return;

		JobAco:
			mes "Are you feeling okay?....";
			emotion 20;
			next;
			mes "[Father Mareusis]";
			mes "...your attire...";
			next;
			mes "[Father Mareusis]";
			mes "You're already are an Acolyte.....";
			next;
			mes "[Father Mareusis]";
			mes "You are not joking with me, are you? Hoho!!..kids these days.";
			emotion 18;
			close;
			

		NotNov:
			mes "I am sorry child.  You have already devoted your life to another profession.  I am afraid that you will no longer be able to devote it to God.";
			close;
			

		JobLess10:
			mes "My child you do not yet possess the necessary skills to serve the lord.";
			mes "Please come back when your faith in God has become stronger";
			next;
			mes "[Father Mareusis]";
			mes "May God bless you.";
			close;
			
}

//Archer Check

function	script	Arc_check	{

		if(BaseJob == Job_Archer) goto sL_Archer;
		if(BaseJob != Job_Novice) goto sL_Other;
		mes "You have made an execellent job choice.";
		mes "Please submit your resume so that I can check your qualifications.";
		next;
		mes "(You hand over your resume)";
		next;
		mes "[Archer Guildsman]";
		if(JobLevel < 10) goto sL_LowLvl;
		set job_archer_q,1;
		return;

		sL_Archer:
			mes "Your free spirited nature tells me that you're already an archer....that and the bow and arrow in your hands...Haha";
			emotion 18;
			close;
			

		sL_Other:
			mes "I'm sorry but you cannot leave your current job to become an Archer...though I can understand why you would want to do so."; 
			close;
			

		sL_LowLvl:
			mes "It seems that you are not qualified to become an Archer yet.  Please take a look at the job requirments once more.";
			close;
			

}

//mage Check
function	script	Mag_check	{
	
		if(BaseJob == 2) goto L_JobMage;
		if(BaseJob != 0) goto L_JobOther;
		mes "Okays, just fill out this application form pleeassse.";
		next;
		mes "(you fill out the form and hand it back to her)";
		next;
		mes "[Expert Mage]";
		if(JobLevel < 10) goto L_JobLvl;
		mes "Oooh~ You have very nice hand writing ^0000dd"+ strcharinfo(0) +"^000000, and more importantly you have met the necessary prerequisites to become a mage.";
		next;
		mes "[Expert Mage]";
		return;

		L_JobMage:
			mes "You should really get yourself a mirror.  Then you could see that you are ^ff0000already a Mage^000000.";
			mes "It may even help you fix up your hair do.";
			emotion 4;
			close;
			

		L_JobOther:
			mes "Oh...I'm sorry.  I know they say 2 is always better than 1, but when it comes to Jobs, it's a No No.";
			mes "Try to stay positive.  Your current job can't be that bad.";
			emotion 22;
			close;
			

		L_JobLvl:
			mes "Oh...I'm sorry.  You need ^ff0000Job level 9^000000 and all of the ^0000ffBasic Skills^000000 before you can become a Mage.";
			mes "Go out and kill some more Fabres okays.";
			emotion 22;
			close;
			

}

//Merchant Check
function	script	Mer_check	{

     		if(BaseJob==5) goto L_JobMer;
		if(BaseJob !=0) goto L_JobOther;
		if(JobLevel < 10) goto L_JobLvl;
		mes "[Chief Mahnsoo]";
		mes "A Merchant you say? Well...";
		next;
		mes "[Chief Mahnsoo]";
		mes "Alright.  First fill out an application form and submit 1000 Zeny for the Memebership Fee.";
		mes "If you don't have enough money right now, you can pay 500 Zeny first and then pay the rest later after you've passed the Merchant License Test.";
		next;
		mes "[Chief Mahnsoo]";
		mes "How does that sound? Are you still interested?";
		return;
	
		L_JobMer:
			mes "[Chief Mahnsoo]";
			mes "Huh? What did you say? You noodle head! Take a good look at yourself.  Your ALREADY A MERCHANT!  Good lord!";
			emotion 1;
			emotion 0;
			close;
			

		L_JobOther:
			mes "[Chief Mahnsoo]";
			mes "We Merchants really don't like people who work during the day, and then go out to crazy bars at night.  When it comes to money, for them it's 'easy come easy go.";
			next;
			mes "[Chief Mahnsoo]";
			mes "Well.. I talked a little too long, I guess... but since you already have an occupation, we don't need you.";
			close;
			

		L_JobLvl:
			mes "[Chief Mahnsoo]";
			mes "I'm sorry but you have to have a Novice Job level of 9 with all 9 of the basic Skills.";
			close;
			
}

//Swordsman Check
function	script	Swo_check	{

		if(BaseJob == Job_Swordman) goto O_1b;
		if(BaseJob != Job_Novice) goto O_1c;
		mes "So you wish to become a Swordsman aye? A very good choice!!  Fill out this application form first.";
		next;
		mes "..(you fill out the form and hand it to him)..";
		next;
		mes "[Master Swordsman]";
		if(JobLevel < 10) goto O_1d;
		return;

		O_1b:
			mes "Muhahaha! You must be kidding me! You're already a swordsman.";
			emotion 18;
			close;

		O_1c:
			mes "Im sorry but you can not hold more than one job at a time and therefore I must refuse your request.";
			next;
			mes "[Master Swordsman]";
			mes "Try picking up a hobby to make use of your spare time. Muhahahahah!!";
			emotion 18;
			close;

		O_1d:
			mes "A hem...., you have yet to learn all of the 'Basic Skills' needed to become a Swordsman.  Please check the requirements again.";
			close;

}
//Thief Check
function	script	Thi_check	{

	if(BaseJob == Job_Novice) return;
	if(BaseJob == Job_Thief) goto L_JobThief;
	mes "[Thief Guide]";
	if(BaseJob==1 || BaseJob==7 || BaseJob==14) goto L_Swordman;
	if(BaseJob==2 || BaseJob==9 || BaseJob==16) goto L_Mage;
	if(BaseJob==3 || BaseJob==11 || BaseJob==19 || BaseJob==20) goto L_Archer;
	if(BaseJob==4 || BaseJob==8 || BaseJob==15) goto L_Acolyte;
	if(BaseJob==5 || BaseJob==10 || BaseJob==18) goto L_Merchant;

		mes "You already have a job.  Stop bothering me and go help out some newbies or something.";
		emotion 21;
		close;

	L_Acolyte:
		mes "What the heck...? Ohhhhhh~GOD... PORING's worshipper, Acolyte...";
		mes "So why aren't you in church praying, instead of wandering about here, huh?";
		close;

	L_Archer:
		mes "What the heck...? Hahahaha~are you a 'Kill Stealing' Archer...?";
		emotion 18;
		close;

	L_Mage:
		mes "What the heck...? Ehhh??? A Circus Sideshow? Make a fire without a Matchstick, will ya?";
		emotion 19;
		close;

	L_Merchant:
		mes "What the heck...? Eeeeeek~Merchant Scammer here...!!!! I am gonna report you to the GM!!!";
		emotion 0;
		close;

	L_Swordman:
		mes "What the heck...? Meh!~Here's another 'Bash' head.  Do me a favor... why don't you go 'BASH', yourself in the head.  Ha!";
		emotion 29;
		close;

L_JobThief:
	mes "[Thief Guide]";
	mes "You're already a thief.....  What do you want from me... go away!";
	emotion 4;
	close;

}