//====================================================================
//Ragnarok Online Swordman jobchange script
//====================================================================
izlude_in.gat,74,172,4	script	剣士ギルド員	119,{
	mes "[剣士ギルド員]";
	mes "わしは、ここ剣士ギルドの";
	mes "転職係！何の用だ？";
	next;
	menu "剣士に転職する。",L1,"剣士について聞く",L2,"剣士転職要件について聞く。",L3,"やめる",L4;
L1:
//転生ノビ処理
	callfunc "jobchanger","剣士ギルド員",1;
if (Class == 1) goto Ltwice;
if (Class != 0) goto LError;
if (change_sword == 5) goto Lchangejob;
if (change_sword >= 1) goto Lcheck;
	mes "[剣士ギルド員]";
	mes "剣士に転職したいか？";
	mes "よし、なら先に剣士転職試験の";
	mes "申し込みをするのだ。";
	next;
	menu "剣士転職の申し込みをする。",-,"やめる。",Lend;
		set change_sword,1;
		savepoint "izlude_in.gat",67,170;
		mes "[剣士ギルド員]";
		mes "そこにサインして…よし、";
		mes "この申込書はすぐ処理させよう。";
		mes "あ、転職要件を満たしたら";
		mes "すぐ転職試験にいけるぞ。";
		mes "やってみるか？";
		next;
		menu "はい",-,"いいえ",L1_2;
			mes "[剣士ギルド員]";
			mes "ほう？さてと、確認してみようか？";
			next;
			goto Lcheck;
		L1_2:
			mes "[剣士ギルド員]";
			mes "そうか…";
			mes "準備が出来たらまた来な。";
			close;
L2:
	mes "[剣士ギルド員]";
	mes "剣士について知りたい？";
	mes "よし、説明しよう！";
	next;
	mes "[剣士ギルド員]";
	mes "剣士の一番大きな特徴は、";
	mes "近接線で最強の威力を";
	mes "発揮できるってことだ！";
	mes "剣士が接近戦に";
	mes "最強な理由は３つ！";
	next;
	mes "[剣士ギルド員]";
	mes "１つ目、他職業に比べて";
	mes "HPがより高い！";
	mes "２つ目、弓と枝を除いた、全ての";
	mes "武器を使える！だから状況によって";
	mes "必要な武器を選べる！";
	next;
	mes "[剣士ギルド員]";
	mes "３つ目、剣士のスキルは、大抵";
	mes "強力な物理打撃を与えるものが多い。";
	mes "簡単な説明だが、これで十分だ。";
	mes "何故かというと、剣士は世界で";
	mes "一番格好いい職業で、そもそも";
	mes "説明などは、必要がないからだ！";
	close;
L3:
	mes "[剣士ギルド員]";
	mes "剣士になりたいのか？";
if (Class == 0) goto L3_1;
	if (Class != 1) mes "しかし、君はもう他の職業に";
	if (Class != 1) mes "なっているだろう？無理だよ。";
	if (Class == 1) mes "……っていうか、";
	if (Class == 1) mes "君はもう剣士だろう……？";
	mes "それでも聞きたい……？";
	mes "まあ、なら教えよう。";
L3_1:
	next;
	mes "[剣士ギルド員]";
	mes "剣士になるためには、";
	mes "まず、初心者スキルポイントが９以上";
	mes "じゃないと駄目だ。君がそれすらも";
	mes "できなかったら、剣士は";
	mes "諦めろ。";
	next;
	mes "[剣士ギルド員]";
	mes "２番目、剣士転職試験を";
	mes "受けなければならない。";
	mes "詳しい内容は実地試験の";
	mes "案内人に聞いてみるのだ。";
	next;
	mes "[剣士ギルド員]";
	mes "まあ、その２つのことを済ませば、";
	mes "剣士になる要件が全部揃うから、";
	mes "好きな時にいつでも剣士に";
	mes "転職できるのだ。";
	close;
L4:
	mes "[剣士ギルド員]";
	mes "ははは！君を見ていると、";
	mes "わしの若い頃を思い出すよ！";
	close;
Lcheck:
	if (getskilllv(1) < 9) goto Llowlv;
	mes "[剣士ギルド員]";
	mes "初心者スキルレベルは十分なのに、";
	mes "実地試験がまだだな。君が、あの";
	mes "基本的な試験にすら合格できないなら、";
	mes "君の剣士転職の夢は、大気圏を";
	mes "突破して、あの宇宙の果てまで";
	mes "遠くなってしまうだろう。";
	next;
	mes "[剣士ギルド員]";
	mes "実地試験は左の方だ。";
	mes "入り口で、剣士ギルド員に";
	mes "話をすれば、通してくれるだろう。";
	close;
Lchangejob:
	mes "[剣士ギルド員]";
	mes "おめでとう！";
	mes "君は、これからけーーんしという";
	mes "素晴らしい職業になるわけだ！";
	mes "これから君を剣士に任命する！";
	next;
	jobchange 1;
	set change_sword,0;
	mes "[剣士ギルド員]";
	mes "剣士になったのをもう一度";
	mes "お祝いする。これから";
	mes "剣士ギルドのため、";
	mes "たくさん力を貸してくれ！";
	close;
Llowlv:
	mes "[剣士ギルド員]";
	mes "おい、君。初心者スキルポイントが、";
	mes "規定水準になっていないな。";
	mes "転職要件をもう一度調べた上で、";
	mes "初心者スキルポイントを";
	mes "上げてからまた来な。";
	close;
Ltwice:
	mes "[剣士ギルド員]";
	mes "うはははは！";
	mes "面白いジョーダンじゃねーか！";
	mes "君はもう剣士だろう？";
	close;
LError:
	mes "[剣士ギルド員]";
	mes "はは！まったく、変なことを言うな！";
	mes "君はもう他の職業に";
	mes "なっているではないか！";
	close;
Lend:
	mes "[剣士ギルド員]";
	mes "そうか……気が変わったら";
	mes "また来な。";
	close;
}
//==============================================================================
izlude_in.gat,62,170,6	script	剣士ギルド員	85,{
	if (Class == 1) goto Ltwice;
	if (Class != 0) goto Lotherjob;
	if (getskilllv(1) < 9) goto Llowlv;
	if (change_sword == 5) goto Lerror;
	if (change_sword >= 1) goto Lwarp;
	mes "[剣士ギルド員]";
	mes "止まれ！剣士転職試験を";
	mes "受けたいなら、転職申込書を";
	mes "書いてからだ！";
	close;
Lwarp:
	warp "izlude_in.gat",39,170;
	end;
Lerror:
	mes "[剣士ギルド員]";
	mes "止まれ！まず中央のギルド員に";
	mes "問い合わせてからだ！";
	close;
Llowlv:
	mes "[剣士ギルド員]";
	mes "止まれ！初心者スキルポイントが";
	mes "９にもならない素人が来る所じゃない！";
	mes "スキルポイントが９以上になったら、";
	mes "転職試験場に入らせるからな。";
	close;
Ltwice:
	mes "[剣士ギルド員]";
	mes "止まれ！ここは初心者実地試験場だ！";
	mes "既に転職したお前が入る理由はない！";
	mes "帰れ！";
	close;
Lotherjob:
	mes "[剣士ギルド員]";
	mes "何者だ！もう他の職業になっている";
	mes "お前が、ここに来るんじゃない！";
	close;
}
//==============================================================================
izlude_in.gat,30,175,4	script	剣士ギルド員	92,{
	mes "[剣士ギルド員]";
	mes "実地試験に関して、簡単に説明しよう！";
	mes "よーく聞いて、あとで変な質問とか";
	mes "しないように！";
	next;
	mes "[剣士ギルド員]";
	mes "この試験の目的は、丈夫な体力と強靭な";
	mes "精神力が必要である剣士の才能が";
	mes "あるかどうかをテストするのだ！";
	mes "もちろん才能がなければ、";
	mes "試験で落ちてしまうだろう。";
	next;
	mes "[剣士ギルド員]";
	mes "試験の^33ff55合格条件^000000は、すごーく簡単だ！";
	mes "試験場の全てのコースを";
	mes "無事に通過して、最後の";
	mes "チェックポイントで待っている試験官に";
	mes "合格認定をもらうだけでいいんだ。";
	next;
	mes "[剣士ギルド員]";
	mes "反対に、放棄宣言をしたり、最後の";
	mes "チェックポイントに到着できなかった";
	mes "場合は不合格になる、もし、放棄宣言を";
	mes "したいなら、各コース入り口に";
	mes "戻ったり、各チェックポイントの";
	mes "関係者に話したらいい。";
	next;
	mes "[剣士ギルド員]";
	mes "試験場は３つのコースになっていて、";
	mes "コースを離脱したら、地下洞窟の";
	mes "ランダムな位置に落ちてしまうから、";
	mes "注意した方がいい。";
	mes "それじゃ、幸運を祈る。";
	close;
}
//==============================================================================
izlude_in.gat,30,163,0	script	試験場職員	105,{
	if (change_sword == 1) goto Lfirst;
	if (change_sword == 2) goto Lsecond;
	if (change_sword == 3) goto Ltherd;
		mes "[試験場職員]";
		mes "む、どうやって入ってきたんだ？";
		close2;
		warp "izlude_in.gat",63,169;
		end;
Lfirst:
	mes "[試験場職員]";
	mes "剣士になりたいのか？ふん、";
	mes "まあ、才能はあるみたいだな。";
	mes "これからの人生に比べたら、ここの";
	mes "苦難は、何ともないだろう！";
	mes "緊張するな！お前ならできる！";
	close2;
	set change_sword,2;
	warp "sword_1-1.gat",10,245;
	end;
Lsecond:
	mes "[試験場職員]";
	mes "失敗したのか…";
	mes "これをもっていけ";
	close2;
	getitem 512,5;
	set change_sword,3;
	warp "sword_1-1.gat",10,245;
	end;

Ltherd:
	mes "[試験場職員]";
	mes "諦めるな！再挑戦だ”";
	close2;
	warp "sword_1-1.gat",10,245;
	end;
}
//==============================================================================
//==============================================================================
sword_1-1.gat,7,245,0	script	#試験場サポーター1	45,1,1,{
	end;
OnTouch:
	mes "[試験場サポーター]";
	mes "受験生 " + strcharinfo(0) + ". 放棄宣言をしますか？";
	next;
	menu "はい.",Lwarp,"いいえ",-;
		warp "sword_1-1.gat",10,245;
		end;
Lwarp:
		mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + " が試験を放棄しました.",0;
		warp "izlude_in.gat",65,165;
		end;
}
//==============================================================================
sword_1-1.gat,8,207,0	script	#試験場サポーター2	45,1,1,{
	end;
OnTouch:
	mes "[試験場サポーター]";
	mes "受験生 " + strcharinfo(0) + ". 放棄宣言をしますか？";
	next;
	menu "はい.",Lwarp,"いいえ",-;
		warp "sword_1-1.gat",11,207;
		end;
Lwarp:
		mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + " が試験を放棄しました.",0;
		warp "izlude_in.gat",65,165;
		end;
}

//==============================================================================
sword_1-1.gat,8,169,0	script	#試験場サポーター3	45,1,1,{
	end;
OnTouch:
	mes "[試験場サポーター]";
	mes "受験生 " + strcharinfo(0) + ". 放棄宣言をしますか？";
	next;
	menu "はい.",Lwarp,"いいえ",-;
		warp "sword_1-1.gat",11,169;
		end;
Lwarp:
		mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + " が試験を放棄しました.",0;
		warp "izlude_in.gat",65,165;
		end;
}
//==============================================================================
//==============================================================================
sword_1-1.gat,192,244,0	script	#試験場サポーター4	45,1,1,{
	end;
OnTouch:
	mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + ".第１ポイント通過",0;
	warp "sword_1-1.gat",215,244;
	end;
}
//==============================================================================
sword_1-1.gat,193,207,0	script	#試験場サポーター5	45,1,1,{
	end;
OnTouch:
	mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + ".第２ポイント通過",0;
	warp "sword_1-1.gat",215,205;
	end;
}
//==============================================================================
sword_1-1.gat,193,168,0	script	#試験場サポーター6	45,1,1,{
	end;
OnTouch:
	mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + ".第３ポイント通過",0;
	warp "sword_1-1.gat",215,167;
	end;
}
//==============================================================================
//==============================================================================
sword_1-1.gat,230,242,2	script	試験場サポーター	105,{
	mes "[試験場サポーター]";
	mes "放棄宣言をするのか？";
	next;
	menu "はい",Lwarp,"いいえ",-;
		mes "[試験場サポーター]";
		mes "よーし！";
		mes "燃える若いパワーで立ち向かうのだ！";
		close;
Lwarp:
		mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + " が試験を放棄しました.",0;
		warp "izlude_in.gat",65,165;
		end;
}
//==============================================================================
sword_1-1.gat,230,204,2	script	試験場サポーター	105,{
	mes "[試験場サポーター]";
	mes "放棄宣言をするのか？";
	next;
	menu "はい",Lwarp,"いいえ",-;
		mes "[試験場サポーター]";
		mes "よーし！";
		mes "燃える若いパワーで立ち向かうのだ！";
		close;
Lwarp:
		mapannounce "sword_1-1.gat","試験場サポーター: 受験生 " + strcharinfo(0) + " が試験を放棄しました.",0;
		warp "izlude_in.gat",65,165;
		end;
}
//==============================================================================
//==============================================================================
sword_1-1.gat,230,245,2	script	医療担当サポーター	105,{
	mes "[医療担当サポーター]";
	mes "ここが第１チェックポイントだ！";
	mes "体力を回復してあげるから頑張れよ！";
	heal 1000,0;
	close;
}
//==============================================================================
sword_1-1.gat,230,207,2	script	医療担当サポーター	105,{
	mes "[医療担当サポーター]";
	mes "ここが第２チェックポイントだ！";
	mes "体力を回復してあげるから頑張れよ！";
	heal 1000,0;
	close;
}
//==============================================================================
sword_1-1.gat,223,167,4	script	mei	92,{
	mapannounce "sword_1-1.gat","mei: 受験生 " + strcharinfo(0) + "、試験に合格しました.",0;
	set change_sword,5;
	mes "[メイ]";
	mes "試験の合格、おめでとうございます！";
	mes "既に合格の旨は、";
	mes "転職管理課に伝えました。";
	mes "ここを出て、中央の転職管理職員の";
	mes "ところに行って下さい。";
	close2;
	warp "izlude_in.gat",66,173;
	end;
}
//==============================================================================
