//====================================================================
// Event Oni
//====================================================================
//勝ちパターン(一番成功率が高い様子)
//　避ける⇒フェイヨン水溶液⇒かたい皮⇒銀の矢
//賞品はジュース各種(偏りなし)
//他は適当にランダム脳内仕様
//ドケビ、アムムトが変(本体、Script中身分離)なのは本鯖同様です。ﾀﾌﾞﾝﾈ
payon.gat,93,75,4	script	警備兵	708,{
	cutin "pay_soldier",2;
	if (event_oni == 1) goto Lfinal;
	mes "[警備兵]";
	mes "今、この町はある問題を抱えています。";
	mes "……住民が鬼に襲われたのです！";
	mes "もし、言い伝えのように鬼が襲って";
	mes "くるとしたら……";
	mes "私たちだけでは町を守りきる";
	mes "ことはできないでしょう……";
	next;
	mes "[警備兵]";
	mes "あの……";
	mes "あなたを経験豊かな冒険者と";
	mes "見込んでお願いします。";
	mes "協力していただけないでしょうか？";
	next;
	menu "わかりました、引き受けましょう！",L1,"私には無理です。",-;
		mes "[警備兵]";
		mes "そうですか、残念です……";
		mes "はぁ、どうしよう……";
		cutin "pay_soldier",255;
		close;
L1:
		mes "[警備兵]";
		mes "本当ですか!?";
		mes "ありがとうございます！";
		mes "町を守っていただくためには";
		mes "まず鬼について知ってもらわないと……";
		next;
		mes "[警備兵]";
		mes "この町の奥にある弓手の村に、";
		mes "物知りなおじいさんがいます。";
		mes "鬼についても詳しいと思いますので";
		mes "一度話を聞いてみては";
		mes "いかがでしょうか？";
		next;
		mes "[警備兵]";
		mes "そうそう、襲われた住民は";
		mes "旅館にいます。";
		mes "どうかよろしくお願いします。";
		cutin "pay_soldier",255;
		close;
Lfinal:
	mes "[警備兵]";
	mes "おお、どこに行っておられたのです？";
	mes "……ん？";
	mes "何ですか、それは？";
	mes "棍棒じゃないですか……";
	mes "ええ？鬼が持っていた武器!?";
	mes "ドケビはそれで人を襲ったのですね！";
	next;
	mes "[警備兵]";
	mes "……";
	mes "え!?襲ったのはドケビじゃない？";
	mes "……";
	mes "そうだったんですか。";
	mes "その昔、町を襲ったのも、";
	mes "アムムトという鬼……";
	next;
	mes "[警備兵]";
	mes "では、言い伝えは";
	mes "間違っていたのか……。";
	mes "なんと……";
	next;
	mes "[警備兵]";
	mes "ああ、すいません。";
	mes "何はともあれ、";
	mes "本当にありがとうございました。";
	next;
	mes "[警備兵]";
	mes "そうだ、実はあの物知りなおじいさんが";
	mes "鬼について尋ねてきたあなたのことを";
	mes "心配していたようなんです。";
	mes "どうかあなたの元気な姿を";
	mes "見せてあげてもらえませんか？";
	cutin "pay_soldier",255;
	close;
}
//====================================================================
pay_arche.gat,140,30,4	script	おじいさん	120,{
	if ((event_oni == 1) && (countitem(1501)>=1)) goto Levent;
	mes "[物知りじい]";
	mes "ん？";
	mes "なんじゃ？";
	mes "何かようかな？";
	next;
	menu "鬼について知りたい",L1,"特に用はないです",-;
		mes "[物知りじい]";
		mes "そうか……";
		close;
	L1:
		mes "[物知りじい]";
		mes "そうか……";
		mes "鬼について知りたいとな。";
		mes "……ふむ……";
		mes "では話すとしようかの。";
		next;
		mes "[物知りじい]";
		mes "昔、鬼と人間は仲が良かったのじゃ。";
		mes "両種族の子供は、いつも一緒に遊んで";
		mes "おった。";
		mes "そんなある日のことじゃ、";
		mes "鬼の子と遊ぶために出かけた子供が";
		mes "寂しそうに帰ってきたのじゃ。";
		next;
		mes "[物知りじい]";
		mes "話を聞くと、もう会えないと";
		mes "言われたらしい。";
		mes "そして……";
		mes "鬼の子が姿を見せなくなってから";
		mes "数日後、冒険者が次々と襲われる";
		mes "事件が起こった。";
		next;
		mes "[物知りじい]";
		mes "冒険者達は鬼に襲われたと言う。";
		mes "町の人々は驚き、戸惑ったが";
		mes "やがて、事件と鬼の子が姿を";
		mes "消した事に関係があるのではないかと";
		mes "考えるようになったんじゃ。";
		next;
		mes "[物知りじい]";
		mes "この事件をきっかけに";
		mes "住民は集会を行った。";
		mes "その結果、町と住民の安全を";
		mes "守るために町から外出を";
		mes "禁止することにした。";
		next;
		mes "[物知りじい]";
		mes "そして、ある日の夜。";
		mes "町が襲われ、荒らされた……";
		next;
		mes "[物知りじい]";
		mes "幸い、どの家からも怪我人は";
		mes "出なかったものの、その夜に";
		mes "多くの人が鬼を見たと話し";
		mes "町には鬼の足跡が";
		mes "たくさん残っておった。";
		next;
		mes "[物知りじい]";
		mes "人々は、今までの事件や";
		mes "町を襲ったのは、やはり鬼の仕業だと";
		mes "判断したのじゃ。";
		mes "その時から鬼とは交流が";
		mes "なくなってしまった……";
		next;
		mes "[物知りじい]";
		mes "まぁ、わしが知っているのは";
		mes "このくらいじゃな。";
		close;
Levent:
	mes "[物知りじい]";
	mes "おお……心配したぞ。";
	mes "鬼のもとへ向かったと聞いてな。";
	mes "じゃが、ふむ……無事で何より。";
	mes "してどうじゃった？";
	mes "鬼を見つけたかの？";
	mes "もしや、鬼を倒したのか？";
	next;
	mes "[物知りじい]";
	mes "ほう、それは……";
	mes "棍棒じゃな？";
	mes "鬼のものかの？";
	mes "すると……";
	mes "鬼を倒してくれたのじゃな！";
	mes "ようやってくれたのぉ。";
	next;
	mes "[物知りじい]";
	mes "……";
	mes "ふむ。";
	mes "……";
	mes "なんと！";
	mes "人を襲ったのはドケビでは";
	mes "ないというのか！";
	next;
	mes "[物知りじい]";
	mes "アムムトという鬼が";
	mes "悪さをしておったと……";
	mes "……";
	mes "昔、悪さをしたのもそやつの";
	mes "仕業じゃったと。";
	next;
	mes "[物知りじい]";
	mes "知らんかった……";
	mes "他にも鬼がおったとは……";
	mes "おぉ……何ということじゃ。";
	mes "わしらは、今までとんでもない";
	mes "間違いをしていたのか……";
	next;
	mes "[物知りじい]";
	mes "わしは……";
	mes "わしは、長い間ドケビを恨んでおった。";
	mes "どうして裏切ったのか、";
	mes "あの時、なぜわしの前から";
	mes "消えたのかと……";
	next;
	mes "[物知りじい]";
	mes "……";
	mes "そなたに教えた言い伝えの人の子とは";
	mes "わしだったのじゃ。";
	mes "わしは、ドケビに裏切られたと";
	mes "ずっと思っていた。";
	mes "しかし……";
	next;
	mes "[物知りじい]";
	mes "裏切ったのは、";
	mes "いや、信頼していなかったのは";
	mes "わしらのほうだったんじゃな。";
	mes "わしらは酷い事をしてしまった。";
	mes "ドケビが恨んでいても";
	mes "仕方がないのぉ……";
	next;
	mes "[物知りじい]";
	mes "……";
	mes "わしはどうすればいいんじゃ";
	mes "どうすれば……";
	mes "……";
	next;
	mes "[物知りじい]";
	mes "なんじゃと!?";
	mes "ドケビは、わしらを";
	mes "恨んでいなかったというのか。";
	mes "それどころか、";
	mes "わしらと遊べなかったのが";
	mes "悲しかったと…";
	next;
	mes "[物知りじい]";
	mes "……";
	mes "そうか……";
	mes "まだ遅くないのかもしれん……";
	next;
	mes "[物知りじい]";
	mes "よければ……";
	mes "その棍棒、わしにもらえんかの。";
	mes "子供らに、この事を話す時に";
	mes "見せてやりたいんじゃ。";
	next;
	menu "もちろん、どうぞ！",Le_1,"嫌です。",-;
		mes "[物知りじい]";
		mes "そうか、残念じゃ……";
		close;
Le_1:
		mes "[物知りじい]";
		mes "ありがとう。";
		mes "そなたがいなければ、";
		mes "わしはこれからもずっとドケビを";
		mes "恨んでいたじゃろう。";
		mes "なんとお礼をいったらいいか……";
		next;
		mes "[物知りじい]";
		mes "そうじゃ、わしはこんな物しか";
		mes "持っておらぬが、どうか";
		mes "受け取ってくだされ。";
		mes "ほんの心ばかりのお礼じゃ。";
		next;
		mes "[物知りじい]";
		mes "ここフェイヨンで作られている物で";
		mes "体に良いと評判なんじゃよ。";
		mes "どうか使ってくだされ……";
		next;
		set @jijirand,rand(4);
		set event_oni,0;
		delitem 1501,1;
		if (@jijirand == 1) goto Lrand1;
		if (@jijirand == 2) goto Lrand2;
		if (@jijirand == 3) goto Lrand3;
			getitem 531,1;goto Lrandend;
	Lrand1:
			getitem 532,1;goto Lrandend;
	Lrand2:
			getitem 533,1;goto Lrandend;
	Lrand3:
			getitem 534,1;
Lrandend:
		mes "[物知りじい]";
		mes "そなたから聞いた真実は、";
		mes "孫たちへ伝えていくとしよう。";
		mes "もちろん、そなたのこともな……";
		close;
}
payon.gat,100,135,4	script	子供	706,{
	mes "[町の少年]";
	mes "怖いよ〜！！";
	mes "僕たち鬼にたべられちゃうのかなぁ……";
	close;
}
//====================================================================
payon.gat,45,130,4	script	住民	50,{
	mes "[町の男性]";
	mes "その昔、町が鬼に襲われたという";
	mes "言い伝えは本当だったのか！";
	mes "どうすればいいんだ。";
	next;
	mes "[町の男性]";
	mes "そういえば……";
	mes "私が幼いころ、寝る前によく";
	mes "鬼の言い伝えを聞かされたんだ。";
	mes "その昔、枕元には必ず";
	mes "^ff0000フェイヨン水溶液^000000が置いてあったな。";
	mes "母親は魔除けだと言っていたが……";
	close;
}
//====================================================================
payon.gat,153,163,4	script	住民	75,{
	mes "[町の女性]";
	mes "人が鬼に襲われたんですって！";
	mes "言い伝えのように";
	mes "町に鬼が来るのでしょうか？";
	close;
}
//====================================================================
payon_in01.gat,177,49,2	script	怪我を負った人	48,{
	mes "[怪我を負った人]";
	mes "言い伝えにある鬼が本当にいたんだ！";
	mes "私はアルベルタからこの町へ帰る途中";
	mes "鬼に襲われて深手を負ったんだ。";
	mes "何とか帰ってこれたが……";
	mes "この怪我じゃ当分外にはでられないよ…";
	next;
	menu "どこで鬼に襲われたの？",L1,"どうやって逃げたの!?",L2,;
L1:
	mes "[怪我を負った人]";
	mes "鬼がいた場所は";
	mes "アルベルタとフェイヨンの";
	mes "ちょうど中間くらいだ。";
	mes "通るときには十分に";
	mes "気をつけた方がいい……";
	close;
L2:
	mes "[怪我を負った人]";
	mes "必死だったから、よく覚えていないけど";
	mes "持ってきた道具をかたっぱしから";
	mes "投げつけたんだ。";
	next;
	mes "[怪我を負った人]";
	mes "えっと……^ff0000矢、銀の矢、";
	mes "ソード、ガード、アックス^000000……";
	mes "他にもあったかも知れないけど……";
	mes "覚えてないなぁ。";
	close;
}
//====================================================================
payon_in01.gat,171,138,2	script	青年	59,{
	mes "[青年]";
	mes "かたい皮に被われたモンスターには";
	mes "物理的な力が通用しないんだ、";
	mes "それらを効果的に退治するには";
	mes "「気」または「魔法」と言う";
	mes "精神的な力だけだ。";
	close;
}
//====================================================================
pay_fild02.gat,105,244,4	script	　	1407,{close;}
pay_fild02.gat,105,244,4	script	ドケビ	111,{
	mes "[ドケビ]";
	mes "オラニ、ナニカヨウカ？";
	next;
	menu "お前を倒しに来た！",L1,"なんでもない。",-;
		mes "[ドケビ]";
		mes "ソカ……";
		close;
L1:
		mes "[ドケビ]";
		mes "ナゼダ？";
		mes "オラタチ、ナニカシタカ？";
		mes "……";
		mes "オラタチ、ヒト、オソウ？";
		mes "ソレ、ナイ。";
		next;
		mes "[ドケビ]";
		mes "オラ、ヒト、ムカシ、ナカヨシ。";
		mes "イマ、アソバナイ、";
		mes "デモ、キライナイ。";
		next;
		mes "[ドケビ]";
		mes "ヒト、オソウ、タブン、アムムト。";
		mes "オラモ、アムムト、オソワレタ。";
		mes "アムムト、ワルイ、デモツヨイ。";
		mes "オラタチ、ニゲタ。";
		mes "ダカラ、ヒト、アソベナクナタ。";
		mes "ヒト、アソベナイ、オラ、カナシイ……";
		next;
		menu "アムムトを倒してくる！",L1_1,"かわいそうに。",-;
			mes "[ドケビ]";
			mes "オラカナシイ……";
			mes "マタ、アソビタイ……";
			close;
		L1_1:
			mes "[ドケビ]";
			mes "ソカ……アムムト、チカクイル……";
			mes "アムムト、キケン、ツヨイ。";
			mes "アムムト、チカヅク、ヨクナイ。";
			next;
			mes "[ドケビ]";
			mes "^ff0000カタイカワ^000000、トオク、";
			mes "ブツケル、イチバン。";
			mes "^ff0000フタツ^000000、モテク、イイ。";
			mes "ムカシ、ナゲタ、";
			mes "アムムト、イタガタ。";
			mes "……シヌナ……";
			close;
}
//====================================================================
pay_fild02.gat,53,128,4	script	　	1301,{close;}
pay_fild02.gat,53,128,4	script	アムムト	111,{
	set @ammut,0;
	if ((countitem(1751)>=1) && (countitem(1089)>=1) && (countitem(935)>=2)) goto Lquest;
	mes "今のままでは勝てそうにない……";
	mes "何か弱点を探す必要がありそうだ。";
	close;
Lquest:
	delitem 1751,1;
	delitem 1089,1;
	delitem 935,2;
	mes "[アムムト]";
	mes "……ニンゲン……";
	mes "ナニシニキタ";
	mes "ドケビ……";
	mes "ニンゲン……";
	mes "キライ！";
	mes "ニンゲンタオス！！";
	next;
	mes "アムムトが突然襲い掛かってきた!!";
	next;
	mes "アムムトはアドレナリンラッシュを";
	mes "使った。";
	mes "アムムトの攻撃速度が増加した。";
	mes "アムムトが連続攻撃を仕掛けてきた。";
	mes "どうする!?";
	next;
	menu "避ける",L1_1,"防御する",L1_2,"受け流す",L1_3;
L1_1:
	mes "スッ……";
	mes " ";
	mes "うまく避けることができた。";
	mes "どうする？";
	goto L2menu;
L1_2:
	mes "ガッ……";
	mes " ";
	mes "何とか耐え凌いだ。";
	mes "どうする？";
	set @ammut,1;
	goto L2menu;
L1_3:
	mes "ドガッ……";
	mes " ";
	mes "受け流すことに失敗した。";
	mes "ダメージを受けた！";
	mes "どうする？";
	set @ammut,2;
L2menu:
	next;
	menu "フェイヨン溶液をぶちまける",L2_1,"銀の矢を地面に刺す。",L2_2,"かたい皮を投げる。",L2_3;
L2_1:
	mes "バシャッ……";
	mes " ";
	mes "アムムトに液体がかかった。";
	mes "アムムトはもがき苦しんでいる。";
	mes "どうやら効果があったようだ……";
	goto Lmemmer;
L2_2:
	mes "ドスッ……";
	mes " ";
	mes "何も起こらなかった……";
	mes "それを見てアムムトが";
	mes "ケラケラ笑っている。";
	set @ammut,@ammut+10;
	goto Lmemmer;
L2_3:
	mes "ビュ……";
	mes " ";
	mes "アムムトはとっさによけた。";
	mes "惜しい！";
	mes "ダメージを与えられなかった。";
	set @ammut,@ammut+20;
Lmemmer:
	next;
	mes "アムムトの攻撃！";
	mes "アムムトはメマーナイトを使って";
	mes "攻撃してきた。";
	next;
	set @ammutrand2,rand(100);
	if (@ammutrand2<= 40) goto Lmemmer2;
	if (@ammutrand2>= 80) goto Lmemmer3;
	if (@ammut==0) goto Lmemmer3;
		mes "ズガガガッ……";
		mes " ";
		mes "避ける事ができず";
		mes "大ダメージを受けた！";
		mes "意識が遠のいていく……";
		close2;
		warp "payon_in01.gat",170,45;end;
	Lmemmer2:
		mes "スッ……";
		mes " ";
		mes "運良く避けることができた。";
		mes "さあ反撃だ！";
		goto L3rdmenu;
	Lmemmer3:
		mes "ズガッ……";
		mes " ";
		mes "回避をこころみたが";
		mes "避けきることができなかった。";
		mes "さあ反撃だ！";
L3rdmenu:
	next;
	menu "フェイヨン水溶液を飲む",L3_1,"銀の矢で突く。",L3_2,"かたい皮を投げる。",L3_3;
L3_1:
	mes "ゴクゴク……";
	mes " ";
	mes "水溶液を飲んだ瞬間";
	mes "体に痺れを感じた！";
	goto Lkonbou;
L3_2:
	mes "シュッ……";
	mes " ";
	mes "アムムトに突進しながら";
	mes "矢で突いたが";
	mes "避けられてしまった！";
	set @ammut,@ammut+100;
	goto Lkonbou;
L3_3:
	mes "バシッ……";
	mes " ";
	mes "見事、アムムトに命中した。";
	mes "痛がっている！";
	set @ammut,@ammut+200;
Lkonbou:
	next;
	mes "アムムトの攻撃！";
	mes "アムムトは持っている棍棒を";
	mes "力いっぱい振り回して";
	mes "こちらに突っ込んできた。";
	next;
	if (@ammut==200) goto Lkonbou3;
	if (@ammut==100) goto Lkonbou4;
	set @ammutrand3,rand(100);
	if (@ammutrand3<= 40) goto Lkonbou3;
	if (@ammutrand3>= 80) goto Lkonbou4;
	Lkonbou2:
		mes "ドガガガッ……";
		mes " ";
		mes "あまりの猛攻に耐え切れず";
		mes "防御をとかれてしまった。";
		mes "そこに強烈な一撃が入った！";
		mes "全身の力が抜けていく……";
		close2;
		warp "payon_in01.gat",165,140;end;
	Lkonbou3:
		mes "ガガッ……";
		mes " ";
		mes "防御することに成功したが";
		mes "すさまじい威力だったため";
		mes "ダメージを受けてしまった。";
		mes "反撃だ！";
		goto L4thmenu;
	Lkonbou4:
		mes "ドテッ……";
		mes " ";
		mes "しかし、アムムトは";
		mes "攻撃する際に転んだ。";
		mes "反撃だ！";
L4thmenu:
		next;
	menu "フェイヨン水溶液を投げつける。",L4_1,"銀の矢を投げつける",L4_2,"かたい皮を投げる。",L4_3;
L4_1:
	mes "ガシャッ……";
	mes " ";
	mes "途中で試験管が割れて";
	mes "アムムトにとどかなかった……";
	goto Lfinal;
L4_2:
	mes "ドスッ……";
	mes " ";
	mes "投げた矢は、アムムトに";
	mes "突きささりダメージを与えた！";
	set @ammut,@ammut+1000;
	goto Lfinal;
L4_3:
	mes "ガゴッ……";
	mes " ";
	mes "アムムトは持っていた";
	mes "棍棒で皮を弾き返した。";
	mes "飛んできた皮をよけきれず";
	mes "ダメージを受けた！";
	set @ammut,@ammut+2000;
Lfinal:
	next;
	if (@ammut==1200) goto Lsucsess;
	set @ammutrand4,rand(100);
	if (@ammutrand4 >= 80) goto Lsucsess;
	mes "ドゴッ……";
	mes " ";
	mes "強烈な体当たりをくらった！！";
	mes "アムムトを追い詰めたが";
	mes "後一歩のところで";
	mes "反撃を受けてしまった！";
	mes "目の前が暗くなっていく……";
	close2;
	warp "payon_in01.gat",165,140;end;
Lsucsess:
	set event_oni,1;
	getitem 1501,1;
	mes "アムムトをこらしめた！！";
	mes "目の前でアムムトが気絶している。";
	mes "アムムトが装備していた";
	mes "棍棒を手に入れた。";
	next;
	mes "鬼を倒した証拠として";
	mes "町にもって帰ろう。";
	close2;
	warp "payon.gat",90,30;end;
}

